Etiquetas y directorios

¿Ha visto cómo algunas aplicaciones muestran a veces una versión abreviada de un nombre de directorio demasiado largo? Estas aplicaciones sustituyen parte de la ruta mediante puntos suspensivos, para que el texto quepa dentro de cierta área. ¿Cómo lo hacen? Resulta que existen dos métodos diferentes, que detallaremos a continuación.

CON LA AYUDA DE WINDOWS

La técnica está basada en una opción de la función DrawText, del API de Windows:

function DrawText(hDC: HDC; lpString: PChar; nCount: Integer;
   var lpRect: TRect; uFormat: UINT): Integer;

Esta función, y su prima DrawTextEx, permiten el uso de la opción DT_PATH_ELLIPSIS en su parámetro uFormat. Conociendo este detalle, es fácil llamar directamente a esta función en la respuesta a algún evento OnPaint, o sencillamente crearnos un nuevo componente, basado en el viejo TLabel, para abreviar los nombres de directorios:

type
   TShortPathLabel = class(TCustomLabel)
   protected
      procedure Paint; override;
   public
      constructor Create(AnOwner: TComponent); override;
   published
      property Alignment;
      property Transparent;
   end;

El constructor se redefine para asignar False a la propiedad WordWrap de la etiqueta, que intencionalmente se ha quedado sin publicar:

constructor TShortPathLabel.Create(AnOwner: TComponent);
begin
   inherited Create(AnOwner);
   WordWrap := False;
   AutoSize := False;
end;

El método de dibujo es muy sencillo, como se muestra a continuación:

procedure TShortPathLabel.Paint;
const
   Alignments: array[TAlignment] of Word = (DT_LEFT, DT_RIGHT, DT_CENTER);
var
   Rect: TRect;
begin
   Rect := ClientRect;
   if not Transparent then
   begin
      Canvas.Brush.Color := Self.Color;
      Canvas.Brush.Style := bsSolid;
      Canvas.FillRect(Rect);
   end;
   Canvas.Brush.Style := bsClear;
   Canvas.DrawText(Canvas.Handle, PChar(Caption), -1, Rect,
      DT_PATH_ELLIPSIS or Alignments[Alignment]);
end;

Se puede mejorar el componente añadiendo una propiedad para decidir si se abrevia o no el nombre de directorio. Además, DrawText permite también utilizar la opción alternativa DT_END_ELLIPSIS, para que los puntos suspensivos se coloquen al final de la cadena. Esta opción quizá sea la más adecuada para los procesos que indican su progreso mostrando el nombre de un fichero.

CON LA AYUDA DE DELPHI

Delphi ha arrastrado desde la versión de 16 bits una serie de clases y procedimientos auxiliares en la unidad FileCtrl. En concreto, ahí se encuentran los componentes de la página Win3.1 relacionados con la selección de ficheros y directorios. La función que nos interesa se llama MinimizeName, y éste es su prototipo:

function MinimizeName(const Filename: TFileName; Canvas: TCanvas;
   MaxLen: Integer): TFileName;

Hay que suministrar un Canvas para que Delphi tenga conocimiento de las condiciones de dibujo que afectan al tamaño del texto final. MaxLen es un valor en píxeles, para indicar la anchura máxima del texto. He aquí un pequeño ejemplo que muestra cómo utilizar MinimizeName:

procedure TForm1.SelectClick(Sender: TObject);
var
   Dir: string;
begin
   if SelectDirectory('Seleccione un directorio', 'C:\', Dir) then
   begin
      Dir := MinimizeName(Dir, Label1.Canvas, Label1.Width);
      Label1.Caption := Dir;
   end;
end;

He aprovechado también para mostrar otra función de Delphi relativamente desconocida: esta vez se trata de SelectDirectory, que permite al usuario seleccionar un directorio mediante un cuadro de diálogo. Existen dos versiones de esta rutina en Delphi 4, ambas marcadas con la directiva overload:

function SelectDirectory(var Directory: string;
  Options: TSelectDirOpts; HelpCtx: Longint): Boolean; overload;
function SelectDirectory(const Caption: string; const Root: WideString;
  out Directory: string): Boolean; overload;

La primera utiliza un cuadro de diálogo de la VCL que muestra, además del inevitable control de selección de directorios, un control TFileListBox para mostrar los ficheros existentes dentro del directorio seleccionado. En cambio, la segunda versión encapsula una llamada a SHBrowseForFolder, que es una función del Shell de Windows, y tiene un aspecto más "estándar". Si realiza un par de pruebas con el componente creado en el primer inciso y con la función MinimizeName, encontrará que esta última ofrece resultados más estéticos que la técnica basada en el API de Windows.